speed-dreams/speed-dreams-code
7
1
Fork 1
Code Issues 9 Pull requests Projects Releases Packages Wiki Activity Actions
speed-dreams-code/packaging/3rdParty-devel/CMakeLists.txt
beaglejoe 18bc616089 Update curl to 7.65.3 
git-svn-id: https://svn.code.sf.net/p/speed-dreams/code/trunk@6690 30fe4595-0a0c-4342-8851-515496e4dcbd

Former-commit-id: c511cfc94fdaa63423cc346103ac295bea1df7ac
Former-commit-id: be8fd0ffbaeeef184982f3a5e23f4dfda847a3a4
2019-07-22 15:19:59 +00:00

478 lines
18 KiB
CMake
Raw Blame History

#
#==============================================================================
#
# file : CMakeLists.txt
# created : Aug 5 2015
# copyright : (C) 2015-2019 Joe Thompson
# email : beaglejoe@users.sourceforge.net
# version : $Id$
#
#==============================================================================
#
# This program is free software: you can redistribute it and/or modify
# it under the terms of the GNU General Public License as published by
# the Free Software Foundation, either version 3 of the License, or
# (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program. If not, see <http://www.gnu.org/licenses/>.
#
#==============================================================================
#
# (hashtag) starts a comment
cmake_minimum_required(VERSION 3.4.0 FATAL_ERROR)
project(3rdParty-2.3)
include(ExternalProject)
include(CMakeDependentOption)
# Setup some defualts...
# Setup the configuration
if(NOT CMAKE_BUILD_TYPE)
set(CMAKE_BUILD_TYPE Release CACHE STRING
"Choose the type of build, options are: None Debug Release RelWithDebInfo MinSizeRel."
FORCE)
message("No CMAKE_BUILD_TYPE specified, defaulting to ${CMAKE_BUILD_TYPE}")
endif(NOT CMAKE_BUILD_TYPE)
# Setup the install prefix.
if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
set(CMAKE_INSTALL_PREFIX "./installed" CACHE PATH "Prefix prepended to install directories" FORCE)
endif(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
if(MINGW)
link_directories(/usr/lib /usr/local/lib)
include_directories(AFTER /usr/include /usr/local/include)
endif(MINGW)
set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_SOURCE_DIR}/cmake/")
message(STATUS "CMAKE_SOURCE_DIR = ${CMAKE_SOURCE_DIR}")
set(EXTERNALS_PREFIX "${CMAKE_CURRENT_BINARY_DIR}/externals" CACHE PATH "")
set(EXTERNALS_INSTALL_DIR "${CMAKE_CURRENT_BINARY_DIR}/3rdParty" CACHE PATH "")
set(EXTERNALS_CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${EXTERNALS_INSTALL_DIR} CACHE PATH "")
set_property(DIRECTORY PROPERTY EP_BASE ${EXTERNALS_PREFIX})
if(WIN32)
set(OPTION_OPENGL_HEADERS true CACHE BOOL "Download the OpenGL headers")
endif(WIN32)
option(OPTION_SDL_1x "Download and Build SDL 1.x" true)
option(OPTION_SDL_2x "Download and Build SDL 2.x" true)
option(OPTION_OPENAL "Download and Build OpenAL" true)
option(OPTION_PLIB "Download and Build PLIB" true)
cmake_dependent_option(OPTION_PLIB_USE_HEAD "Download and Build PLIB from the latest revision" true "OPTION_PLIB" false)
option(OPTION_JPEG "Download and Build libjpeg" true)
option(OPTION_FREESOLID "Download and Build FreeSOLID" true)
option(OPTION_ENET "Download and Build Enet" true)
option(OPTION_OGG "Download and Build libogg" true)
option(OPTION_VORBIS "Download and Build libvorbis" true)
option(OPTION_EXPAT "Download and Build Expat" true)
option(OPTION_ZLIB "Download and Build zlib" true)
option(OPTION_PNG "Download and Build libpng" true)
option(OPTION_SQLITE3 "Download and Build sqlite3" false)
option(OPTION_FREETYPE "Download and Build FreeType" true)
option(OPTION_CURL "Download and Build curl" true)
option(OPTION_OSG "Download and Build OpenSceneGraph" true)
# CMAKE_BUILD_TYPE does NOT work for Visual Studio or Xcode
# need to switch on configuration somehow
# or limit the choices
if(CMAKE_BUILD_TYPE MATCHES "Debug")
set(SUPER_BUILD_POSTFIX "d")
else()
set(SUPER_BUILD_POSTFIX "")
endif()
# OpenGL extensions (Windows only??)
message(STATUS "OpenGL extensions (Windows only??)")
if(WIN32 AND OPTION_OPENGL_HEADERS)
ExternalProject_Add(OpenGL-headers
URL ${CMAKE_CURRENT_SOURCE_DIR}/patches/openglheaders.zip
URL_HASH SHA256=e66ae96912231de021e17c80a978765c126b26cfde1103f63e9f33e4780f7fad
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS})
endif(WIN32 AND OPTION_OPENGL_HEADERS)
if(OPTION_SDL_1x)
ExternalProject_Add(SDL-1.2.15
URL https://www.libsdl.org/release/SDL-1.2.15.tar.gz
URL_HASH SHA256=d6d316a793e5e348155f0dd93b979798933fb98aa1edebcc108829d6474aad00
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
DEPENDS OpenGL-headers
)
ExternalProject_Add_Step(SDL-1.2.15 sdl1x_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/sdl-1.2.15.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
endif(OPTION_SDL_1x)
# TODO - need to disable SDL2 static (it is overwritten by dll's SDL2.lib)
# message(WARNING "TODO - need to disable SDL2 static (it is overwritten by dll's SDL2.lib)")
if(OPTION_SDL_2x)
set(SDL2_PROJECT SDL2-2.0.9)
set(SDL2_ARGS ${EXTERNALS_CMAKE_ARGS} -DSDL_STATIC=Off -DSDL_CMAKE_DEBUG_POSTFIX=)
# set(SDL2_ARGS ${EXTERNALS_CMAKE_ARGS} -DSDL_STATIC=Off)
ExternalProject_Add(${SDL2_PROJECT}
URL https://www.libsdl.org/release/SDL2-2.0.9.tar.gz
URL_HASH SHA256=255186dc676ecd0c1dbf10ec8a2cc5d6869b5079d8a38194c2aecdff54b324b1
CMAKE_ARGS ${SDL2_ARGS}
DEPENDS OpenGL-headers
)
message(WARNING "Remove the step below when SDL2 CMake is fixed")
ExternalProject_Add_Step(${SDL2_PROJECT} sdl2_fix_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/sdl-2.0.9.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
# end message(WARNING "Remove the step below when SDL2 CMake is fixed")
else(OPTION_SDL_2x)
set(SDL2_PROJECT )
endif(OPTION_SDL_2x)
if(OPTION_OPENAL)
if(MSVC_VERSION LESS 1900)
message("openal-soft versions newer than 1.18.2 need Visual Studio 2015")
ExternalProject_Add(openal-soft-1.18.2
URL http://www.openal-soft.org/openal-releases/openal-soft-1.18.2.tar.bz2
URL_HASH SHA256=9f8ac1e27fba15a59758a13f0c7f6540a0605b6c3a691def9d420570506d7e82
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS})
ExternalProject_Add_Step(openal-soft-1.18.2 openal_patch_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/openal-soft-1.18.2.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
else(MSVC_VERSION LESS 1900)
ExternalProject_Add(openal-soft-1.19.1
URL http://www.openal-soft.org/openal-releases/openal-soft-1.19.1.tar.bz2
URL_HASH SHA256=5c2f87ff5188b95e0dc4769719a9d89ce435b8322b4478b95dd4b427fe84b2e9
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS})
endif(MSVC_VERSION LESS 1900)
endif(OPTION_OPENAL)
if(OPTION_PLIB)
if(OPTION_PLIB_USE_HEAD)
ExternalProject_Add(plib-1.8.5-head
SVN_REPOSITORY svn://svn.code.sf.net/p/plib/code/trunk
SVN_REVISION -r2173 #-r2173 as of 2012-08-24 can also use -rHEAD, but specific revision is supposed to prevent calling svn update
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
DEPENDS OpenGL-headers
)
ExternalProject_Add_Step(plib-1.8.5-head plib_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/plib-1.8.5.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
else(OPTION_PLIB_USE_HEAD)
ExternalProject_Add(plib-1.8.5
URL http://plib.sourceforge.net/dist/plib-1.8.5.tar.gz
URL_HASH SHA256=485b22bf6fdc0da067e34ead5e26f002b76326f6371e2ae006415dea6a380a32
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
DEPENDS OpenGL-headers
)
ExternalProject_Add_Step(plib-1.8.5 plib_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/plib-1.8.5.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
endif(OPTION_PLIB_USE_HEAD)
endif(OPTION_PLIB)
if(OPTION_JPEG)
set(JPG_PROJECT jpeg-9c)
ExternalProject_Add(${JPG_PROJECT}
URL http://ijg.org/files/jpegsrc.v9c.tar.gz
URL_HASH SHA256=650250979303a649e21f87b5ccd02672af1ea6954b911342ea491f351ceb7122
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
)
ExternalProject_Add_Step(${JPG_PROJECT} jpeg_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/jpeg-9c.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
ExternalProject_Add_Step(${JPG_PROJECT} jpeg_config
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"<SOURCE_DIR>/jconfig.vc"
"<SOURCE_DIR>/jconfig.h"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
else(OPTION_JPEG)
set(JPG_PROJECT )
endif(OPTION_JPEG)
if(OPTION_FREESOLID)
#message(WARNING "TODO - need to decide between the patches for FreeSOLID-2.1.1 OR FreeSOLID-2.1.2")
#ExternalProject_Add(FreeSOLID-2.1.1
# DOWNLOAD_NAME FreeSOLID-2.1.1.zip
# URL https://sourceforge.net/projects/freesolid/files/FreeSOLID/FreeSOLID-2.1.1.zip/FreeSOLID-2.1.1.zip/download
# URL_HASH SHA256=5a4f8576e27223f03ad0add76a79b06db6cd8f15c8d2767ea35e0c540ba1bee8
# CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
# UPDATE_COMMAND ""
# PATCH_COMMAND ""
# CONFIGURE_COMMAND ""
# BUILD_COMMAND ""
# INSTALL_COMMAND ""
# )
set(FreeSOLID_ARGS ${EXTERNALS_CMAKE_ARGS} -D'CMAKE_DEBUG_POSTFIX=""')
ExternalProject_Add(FreeSOLID-2.1.2
DOWNLOAD_NAME FreeSOLID-2.1.2.zip
URL https://sourceforge.net/projects/freesolid/files/FreeSOLID-2.1.2.zip/download
URL_HASH SHA256=89edc6afdd9d60c8020b2b865b61558c86a8928dc6f1773b9f4708b5c28eb873
CMAKE_ARGS ${FreeSOLID_ARGS}
)
ExternalProject_Add_Step(FreeSOLID-2.1.2 freesolid_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/FreeSOLID-2.1.2.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
endif(OPTION_FREESOLID)
if(OPTION_ENET)
set(ENET_PROJECT enet-1.3.14)
ExternalProject_Add(${ENET_PROJECT}
URL http://enet.bespin.org/download/enet-1.3.14.tar.gz
URL_HASH SHA256=98f6f57aab0a424469619ed3047728f0d3901ce8f0dea919c11e7966d807e870
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
)
ExternalProject_Add_Step(${ENET_PROJECT} enet_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/enet-1.3.14.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
else(OPTION_ENET)
set(ENET_PROJECT )
endif(OPTION_ENET)
if(OPTION_OGG)
ExternalProject_Add(libogg-1.3.3
URL http://downloads.xiph.org/releases/ogg/libogg-1.3.3.tar.gz
URL_HASH SHA256=c2e8a485110b97550f453226ec644ebac6cb29d1caef2902c007edab4308d985
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
)
ExternalProject_Add_Step(libogg-1.3.3 libogg_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/libogg-1.3.3.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
endif(OPTION_OGG)
if(OPTION_VORBIS)
ExternalProject_Add(libvorbis-1.3.6
URL http://downloads.xiph.org/releases/vorbis/libvorbis-1.3.6.tar.gz
URL_HASH SHA256=6ed40e0241089a42c48604dc00e362beee00036af2d8b3f46338031c9e0351cb
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
DEPENDS "libogg-1.3.3"
)
ExternalProject_Add_Step(libvorbis-1.3.6 libvorbis_add_cmake
COMMAND ${CMAKE_COMMAND} -E copy_if_different
"${CMAKE_SOURCE_DIR}/patches/libvorbis-1.3.6.CMakeLists.txt"
"<SOURCE_DIR>/CMakeLists.txt"
DEPENDEES update # do after update
DEPENDERS patch # do before patch
)
endif(OPTION_VORBIS)
if(OPTION_EXPAT)
set(EXPAT_PROJECT expat-2.2.7)
#disable building unneeded sub projects (they failed with VS2008)
set(EXPAT_ARGS ${EXTERNALS_CMAKE_ARGS} -DBUILD_tests=off -DBUILD_examples=off -DBUILD_tools=off -DCMAKE_DEBUG_POSTFIX='')
ExternalProject_Add(${EXPAT_PROJECT}
DOWNLOAD_NAME ${EXPAT_PROJECT}.tar.bz2
URL https://sourceforge.net/projects/expat/files/expat/2.2.7/expat-2.2.7.tar.bz2/download
URL_HASH SHA256=cbc9102f4a31a8dafd42d642e9a3aa31e79a0aedaa1f6efd2795ebc83174ec18
CMAKE_ARGS ${EXPAT_ARGS}
#UPDATE_COMMAND ""
#PATCH_COMMAND ""
#CONFIGURE_COMMAND ""
#BUILD_COMMAND ""
#INSTALL_COMMAND ""
)
else(OPTION_EXPAT)
set(EXPAT_PROJECT )
endif(OPTION_EXPAT)
if(OPTION_ZLIB)
set(ZLIB_PROJECT zlib-1.2.11)
#set(ZLIB_ARGS ${EXTERNALS_CMAKE_ARGS} -DSKIP_INSTALL_LIBRARIES=On -DSKIP_INSTALL_LIBRARIES=On -D'CMAKE_DEBUG_POSTFIX=""')
#set(ZLIB_ARGS ${EXTERNALS_CMAKE_ARGS} -D'CMAKE_BUILD_POSTFIX=hello')
ExternalProject_Add(${ZLIB_PROJECT}
DOWNLOAD_NAME ${ZLIB_PROJECT}.tar.gz
URL https://sourceforge.net/projects/libpng/files/zlib/1.2.11/zlib-1.2.11.tar.gz/download
URL_HASH SHA256=c3e5e9fdd5004dcb542feda5ee4f0ff0744628baf8ed2dd5d66f8ca1197cb1a1
#CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS} -DBUILD_SHARED_LIBS:BOOL=on
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
#UPDATE_COMMAND ""
PATCH_COMMAND ${CMAKE_COMMAND} -E remove -f <SOURCE_DIR>/zconf.h
#CONFIGURE_COMMAND ""
#BUILD_COMMAND ""
#INSTALL_COMMAND ${CMAKE_COMMAND} install(TARGETS zlibstatic)
)
ExternalProject_Add_Step(${ZLIB_PROJECT} sd_zlib_remove_dll
COMMAND "${CMAKE_COMMAND}" -E remove -f ${EXTERNALS_INSTALL_DIR}/bin/zlib${SUPER_BUILD_POSTFIX}.dll
DEPENDEES install
)
ExternalProject_Add_Step(${ZLIB_PROJECT} sd_zlib_remove_lib
COMMAND "${CMAKE_COMMAND}" -E remove -f ${EXTERNALS_INSTALL_DIR}/lib/zlib${SUPER_BUILD_POSTFIX}.lib
DEPENDEES sd_zlib_remove_dll
)
ExternalProject_Add_Step(${ZLIB_PROJECT} sd_zlib_rename_lib
COMMAND "${CMAKE_COMMAND}" -E rename ${EXTERNALS_INSTALL_DIR}/lib/zlibstatic${SUPER_BUILD_POSTFIX}.lib ${EXTERNALS_INSTALL_DIR}/lib/zlib.lib
DEPENDEES sd_zlib_remove_lib
)
else(OPTION_ZLIB)
set(ZLIB_PROJECT )
endif(OPTION_ZLIB)
if(OPTION_PNG)
set(PNG_PROJECT libpng-1.6.37)
set(PNG_ARGS ${EXTERNALS_CMAKE_ARGS} -DPNG_SHARED=off -DPNG_TESTS=off -DCMAKE_DEBUG_POSTFIX='')
ExternalProject_Add(${PNG_PROJECT}
DOWNLOAD_NAME ${PNG_PROJECT}.tar.gz
URL https://sourceforge.net/projects/libpng/files/libpng16/1.6.37/libpng-1.6.37.tar.gz/download
URL_HASH SHA256=daeb2620d829575513e35fecc83f0d3791a620b9b93d800b763542ece9390fb4
CMAKE_ARGS ${PNG_ARGS}
DEPENDS ${ZLIB_PROJECT}
)
ExternalProject_Add_Step(${PNG_PROJECT} sd_libpng_rename
COMMAND "${CMAKE_COMMAND}" -E rename ${EXTERNALS_INSTALL_DIR}/lib/libpng16_static${SUPER_BUILD_POSTFIX}.lib ${EXTERNALS_INSTALL_DIR}/lib/libpng.lib
DEPENDEES install
)
else(OPTION_PNG)
set(PNG_PROJECT )
endif(OPTION_PNG)
if(OPTION_SQLITE3)
# may only be needed for Simon's replay stuff
ExternalProject_Add(sqlite3-3.25.3
URL https://www.sqlite.org/2018/sqlite-autoconf-3250300.tar.gz
URL_HASH SHA256=00ebf97be13928941940cc71de3d67e9f852698233cd98ce2d178fd08092f3dd
CMAKE_ARGS ${EXTERNALS_CMAKE_ARGS}
UPDATE_COMMAND ""
PATCH_COMMAND ""
CONFIGURE_COMMAND ""
BUILD_COMMAND ""
INSTALL_COMMAND ""
)
endif(OPTION_SQLITE3)
# ========== For OpenSceneGraph =============
if(OPTION_FREETYPE)
set(FREETYPE_PROJECT freetype-2.10.1)
set(FREETYPE_ARGS ${EXTERNALS_CMAKE_ARGS} -DBUILD_SHARED_LIBS:BOOL=false
-DDISABLE_FORCE_DEBUG_POSTFIX:BOOL=true
-DCMAKE_DISABLE_FIND_PACKAGE_BZip2=TRUE
-DCMAKE_DISABLE_FIND_PACKAGE_HarfBuzz=TRUE
-DCMAKE_DISABLE_FIND_PACKAGE_PNG=TRUE
-DCMAKE_DISABLE_FIND_PACKAGE_ZLIB=TRUE)
ExternalProject_Add(${FREETYPE_PROJECT}
DOWNLOAD_NAME ft2100.zip
URL https://sourceforge.net/projects/freetype/files/freetype2/2.10.1/ft2101.zip/download
URL_HASH SHA256=6f22061c6972395526acf9e311c96ce3f900e4c713d8746c659af0a2bef685eb
CMAKE_ARGS ${FREETYPE_ARGS}
DEPENDS ${ZLIB_PROJECT} ${PNG_PROJECT}
)
else(OPTION_FREETYPE)
set(FREETYPE_PROJECT )
endif(OPTION_FREETYPE)
if(OPTION_CURL)
set(CURL_PROJECT curl-7.65.3)
set(CURL_ARGS ${EXTERNALS_CMAKE_ARGS} -DBUILD_TESTING=Off -DCMAKE_DEBUG_POSTFIX=)
ExternalProject_Add(${CURL_PROJECT}
URL https://curl.haxx.se/download/curl-7.65.3.tar.bz2
URL_HASH SHA256=0a855e83be482d7bc9ea00e05bdb1551a44966076762f9650959179c89fce509
CMAKE_ARGS ${CURL_ARGS}
DEPENDS ${ZLIB_PROJECT}
)
else(OPTION_CURL)
set(CURL_PROJECT )
endif(OPTION_CURL)
if(OPTION_OSG)
set(OSG_ARGS ${EXTERNALS_CMAKE_ARGS} -DCMAKE_DEBUG_POSTFIX='' -DUSE_3RDPARTY_BIN=Off)
ExternalProject_Add(osg-OpenSceneGraph-3.6.3
URL https://github.com/openscenegraph/OpenSceneGraph/archive/OpenSceneGraph-3.6.3.zip
URL_HASH SHA256=d8f237e76393e4c749b25321d3735d2c4e5b8c7076f9826213eb0cf8eeca0031
CMAKE_ARGS ${OSG_ARGS}
DEPENDS ${ZLIB_PROJECT} ${CURL_PROJECT} ${FREETYPE_PROJECT} OpenGL-headers ${JPG_PROJECT} ${PNG_PROJECT} SDL-1.2.15 ${SDL2_PROJECT}
)
endif(OPTION_OSG)
#add_subdirectory(src)
# no-output target, for having some files available in IDEs.
set(DOCSOURCES COPYING LICENSE readme.txt)
add_custom_target(rootdoc SOURCES ${DOCSOURCES})
file(GLOB_RECURSE _INFO_FILES "${EXTERNALS_PREFIX}/Stamp/*info.txt")
# ========== Installation =============
install(FILES ${_INFO_FILES} DESTINATION ${EXTERNALS_INSTALL_DIR}/source_info)
install(FILES ${DOCSOURCES} DESTINATION ${EXTERNALS_INSTALL_DIR})
install(DIRECTORY Licenses/ DESTINATION ${EXTERNALS_INSTALL_DIR}/Licenses)
install(DIRECTORY ${EXTERNALS_INSTALL_DIR} DESTINATION .)
# ========== Packaging =============
if(MSVC)
if(CMAKE_CL_64)
set(SD_PACKAGE_FILE_NAME ${CMAKE_PROJECT_NAME}-win64-${CMAKE_C_COMPILER_ID}-${CMAKE_C_COMPILER_VERSION}-${CMAKE_BUILD_TYPE})
else(CMAKE_CL_64)
set(SD_PACKAGE_FILE_NAME ${CMAKE_PROJECT_NAME}-win32-${CMAKE_C_COMPILER_ID}-${CMAKE_C_COMPILER_VERSION}-${CMAKE_BUILD_TYPE})
endif(CMAKE_CL_64)
else(MSVC)
set(SD_PACKAGE_FILE_NAME ${CMAKE_PROJECT_NAME}-${CMAKE_C_COMPILER_ID}-${CMAKE_C_COMPILER_VERSION}-${CMAKE_BUILD_TYPE})
endif(MSVC)
set(CPACK_PACKAGE_FILE_NAME ${SD_PACKAGE_FILE_NAME} CACHE STRING "")
set(CPACK_GENERATOR "ZIP")
include(CPack)
Reference in a new issue View git blame Copy permalink